/* Adam Murray, 2009    
http://compusition.com */

BouncingBall[] balls = new BouncingBall[20];

float increment = 0.035;
float zoff = 0.0;  
float zincrement = 0.01; 

void setup() {
  size(450,450);
  strokeWeight(2);
  smooth();
  background(0);
  for(int i=0; i<balls.length; i++) {
    balls[i] = new BouncingBall();
  }
}

void draw() {
  drawBackground();

  // the ground:
  stroke(0,100,0);
  strokeWeight(20);
  line(0,height-1,width,height-1);
  
  stroke(255,120,0,70);
  strokeWeight(1);
  for(int i=0; i<balls.length; i++) {
    balls[i].draw();
  }
}

void drawBackground() {
  noStroke();
  float xoff = 0.0; // Start xoff at 0
  float xinc = random(7.0) + 13;
  float yinc = random(4.0) + 14;
  for (int x = -20; x < width; x+=xinc) {
    xoff += increment;  
    float yoff = 0.0;   
    for (int y = -20; y < height; y+=yinc) {
      yoff += increment; 
      float b = noise(xoff,yoff,zoff)*255;
      float r = noise(xoff,yoff,zoff*2)*100;      
      fill(r,0,b,90);
      fill(r,0,b,90);
      rect(x,y,14,17);
    }
  }
  zoff += zincrement;
}

class BouncingBall {
  float x, y;
  float v, a; // velocity and acceleration
  int d; // ball diameter
  boolean stopped;
  int alpha;
  int gcolor;
  int bcolor;
  
  public BouncingBall() {
    v = 0;
    a = 0.8;
    d = 25;
    init();
    // create a random delay for the initial drop:
    stopped = true;
    alpha = int(random(255));
  } 
  
  public void init() {
    x = random(width);
    y = -2*d;
    stopped = false;
    alpha = 235;
    gcolor = int(random(170)+70);
    bcolor = int(random(170)+70);
  }
  
  public void draw() {
    fill(240,gcolor,bcolor,alpha);
    ellipse(x,y,d,d);
    update();
  }
  
  public void update() {
    if(stopped) {
      if(alpha > 0) {
        alpha --;
        return;
      }
      init();
    }
    y += v;
    x += random(1.0)-0.5;
    v += a;
    if(y > height-d) {
      v -= random(3.0)+v/5.0;
      if(v < 0) {
        stopped = true;
      }
      v *= -1;
      y = height-d;
    }   
  }
}